#include "colors.inc"
#include "textures.inc"


#declare SEED = seed(324923);

// command line: povray tori.pov +w512 +h512 +A0.3 +KI0 +KF1 +KFI0 +KFF7 +KC

#include "skies.inc"
sky_sphere { S_Cloud5 }

camera {
  up y
  right x
  angle 90
  location <0,3,0>
  // Looking directions (ordered like in node.lua)
  //look_at <0,3,0> + z
  //look_at <0,3,0> + x
  //look_at <0,3,0> - z
  //look_at <0,3,0> - x
  //look_at <0,3,0> + y
  look_at <0,3,0> - y
}

light_source { <0,3,0> color White*1.5 shadowless }

// The big torus
union {
#declare ti = 0;
#declare tcount=40;
#while (ti < tcount)
  torus {
    1, 0.08
    pigment { color White }
    rotate x * 90
    translate y*3
    rotate x * ti*360/tcount 
  }
  #declare ti = ti+1;
#end
// the clock runs in [0,1[
rotate x * -clock*360/tcount
}

// the ladder

torus {
  2.5, 0.01
  rotate z*90
  pigment { color Gray }
  translate x*0.2
}
torus {
  2.5, 0.01
  rotate z*90
  pigment { color Gray }
  translate x*-0.2
}
#declare li = 0;
#declare lcount=100;
#while (li < lcount)
  union {
    cylinder {
      <-0.2,2.5,0> <0.2,2.5,0> 0.01
      texture { 
        EMBWood1
	scale 0.02
	translate <rand(SEED)*5, rand(SEED)*5, rand(SEED)*5> 
      }
    }
    sphere { <-0.2,2.5,0> 0.02 pigment { color Gray } }
    sphere { < 0.2,2.5,0> 0.02 pigment { color Gray } }
    cylinder {
      <-0.2,2.5,0> <-0.2,2.8,0> 0.01
      pigment { color Gray }
    }
    sphere { 
      <-0.2,2.8,0> 0.02 
      texture { Gold_Metal }
    }
    rotate x * (li+0.3)*360/lcount
  }
  #declare li = li+1;
#end

// Some random objects:


#macro randob()
  #local ob_type = rand(SEED) * 2;
  #if (ob_type < 1)
    sphere { 0, 1
  #else
    box { -1, 1 
  #end
      rotate <rand(SEED)*360,rand(SEED)*360,rand(SEED)*360>
      scale 3 * rand(SEED)
      translate x*(20+rand(SEED)*20)
      rotate <rand(SEED)*360,rand(SEED)*360,rand(SEED)*360>

      pigment { color rgb <rand(SEED), rand(SEED), rand(SEED)> }
   }
#end

#declare i = 0;
#while (i < 300)
  randob()
  #declare i = i+1;
#end